Forensic Focus - Computer Forensics, Computer Forensic Training, Digital Forensics
LoginRegisterForumsColumnistsPapersEducationGraduatesReviewsInterviewsNewsletterJobsEventsBlogAdvertise
Search Forensic Focus
Custom Search

Find us on Facebook
Follow Forensic Focus on Twitter
Columnists
"I erred." "I was mistaken."
Craig Ball
Single Sign On
Simon Biles
Copyright and games console modification
Dan Gaskell
To GUI or not to GUI?
Chris Hargreaves
'Web 2.0' as evidence
Sean McLinden
Sometimes it’s all about timing
Sam Raincock
Avoiding common job application errors
David Sullivan
Scalability: A Big Headache
Dominik Weber
Graduate Recruitment

computer forensics graduate jobs

Main Menu
MY ACCOUNT
COMMUNITY
EMPLOYMENT
EDUCATION
RESOURCES
MISC
Follow Forensic Focus

Join newsletter

Join LinkedIn group

Follow on Twitter

Subscribe to news

Subscribe to forums

Subscribe to blog

Subscribe to tweets

Members' blogs

External feeds

Bookmark & share: Bookmark and Share

Computer Forensics Newsletter
Newsletter

You must be a
registered user
to receive our newsletter

Register Now!

Mounting an image
Go to page Previous  1, 2, 3, 4, 5, 6, 7  Next
Post new topic   Reply to topic   Printer Friendly Page     Forum Index -> General Discussion
View previous topic :: View next topic  
Author Message
jaclaz
Senior Member


Joined: Nov 16, 2007
Posts: 420
Location: Near Florence - Italy

PostPosted: Sun Nov 18, 2007 10:42 am    Post subject: Re: Mounting an image Reply with quote

I simply forgot that I already had put together a small batch to help creating a .pln file for a RAW image:
Code::
@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
SETLOCAL ENABLEEXTENSIONS
SET /A HEADS=255
SET /A SECTORS=63

ECHO.
ECHO makepln.cmd: small batch file to create a .pln descriptor file
ECHO              for RAW disk images to be used with VDK.EXE to 
ECHO              mount the image with the correct geometry
ECHO Author:      jaclaz http://home.graffiti.net/jaclaz:graffiti.net/
ECHO.

IF %1.==/?. GOTO :Usage
IF %1.==. GOTO :Interactive

IF NOT EXIST %1 ECHO File NOT FOUND &GOTO :Interactive
CALL :Setvars %1
IF NOT %2.==. SET HEADS=%2
IF NOT %3.==. SET SECTORS=%3
GOTO :DOIT

:Interactive
ECHO Please input filename of the imagefile:
SET /P imgfile=
ECHO Imgfile is %imgfile%
CALL :Setvars %imgfile%
IF NOT EXIST %imgP%%imgN%%imgE% ECHO File NOT FOUND &GOTO :Interactive
ECHO Please input number of Heads for the imagefile [ENTER] for default 255:
SET /P HEADS=
REM SET /A HEADS=%HEADS%
ECHO Please input number of Sectors for the imagefile [ENTER] for default 63:
SET /P SECTORS=
REM SET /A SECTORS=%SECTORS%


:DOIT
FOR /F "tokens=3 delims= " %%A in ('DIR /-C %imgP%%imgN%%imgE% ^|FIND "%imgN%%imgE%"') DO SET /A TOTsectors=%%A/512
DIR /-C %imgP%%imgN%%imgE% |FIND "%imgN%%imgE%"
ECHO Tot sectors are %TOTsectors%
SET /A CYLYNDERS=%totsectors%/%SECTORS%/%HEADS%
:CheckSize
SET /A CheckCyl=%CYLYNDERS%*%SECTORS%*%HEADS%
IF NOT %CheckCyl% LEQ %totsectors% SET /A CYLYNDERS=%CYLYNDERS%-1&GOTO :CheckSize

IF %CYLYNDERS% LEQ 0 ECHO ERROR! Image too little for this geometry.&PAUSE&goto :EOF

ECHO.
ECHO The Following will be written to %imgP%%imgN%.pln:
CALL :Writefile CON
SET Confirm=
ECHO.
ECHO Type Y to confirm, Enter to abort:
SET /P Confirm=
IF /I NOT %Confirm%.==Y. PAUSE&GOTO :EOF
CALL :Writefile "%imgN%.pln"
ECHO File  %imgP%%imgN%.pln written.
PAUSE
GOTO :EOF

:Setvars
%~d1
CD %~dp1
SET imgN=%~n1
SET imgE=%~x1
SET imgP=%~dp1
GOTO :EOF

:Writefile
(
ECHO DRIVETYPE ide
ECHO CYLINDERS %CYLYNDERS%
ECHO HEADS     %HEADS%
ECHO SECTORS   %SECTORS%
ECHO ACCESS "%imgN%%imgE%" 0 %TOTsectors%
) > %1
GOTO :EOF

:Usage
ECHO Usage:
ECHO makepln.cmd [filename] [heads] [sectors]
ECHO Examples:
ECHO makepln.cmd C:\testimg.img 16 63
ECHO makepln.cmd C:\testimg.img (will default to Nx255x63)
ECHO Long filenames are OK, as long as given inside double quotes
ECHO If no parameters are given, will enter interactive mode
GOTO :EOF 


Last edited by jaclaz on Wed Apr 01, 2009 3:11 am; edited 1 time in total
Back to top
View user's profile
jaclaz
Senior Member


Joined: Nov 16, 2007
Posts: 420
Location: Near Florence - Italy

PostPosted: Fri Nov 28, 2008 12:34 pm    Post subject: Re: Mounting an image Reply with quote

@keydet89

FYI, Olof has recently released a newish version of IMDISK that (finally) "automaps" the partition:
www.boot-land.net/foru...0&start=20
Wink


jaclaz
Back to top
View user's profile
MMachor
Member


Joined: Apr 25, 2008
Posts: 69
Location: Canton, OH

PostPosted: Sun Nov 30, 2008 1:17 pm    Post subject: Re: Mounting an image Reply with quote

Ok, along the lines of this post, does anyone have any known image mounting software that will work with Windows Vista? I have Smart Mount, ImDisk, FTK Imager. Get the same problem with all of them, access is denied when trying to mount image as a drive. I've already checked the permissions and have full access to the image. Any ideas?
Back to top
View user's profile Visit poster's website
jaclaz
Senior Member


Joined: Nov 16, 2007
Posts: 420
Location: Near Florence - Italy

PostPosted: Sun Nov 30, 2008 7:20 pm    Post subject: Re: Mounting an image Reply with quote

MMachor wrote:
Ok, along the lines of this post, does anyone have any known image mounting software that will work with Windows Vista? I have Smart Mount, ImDisk, FTK Imager. Get the same problem with all of them, access is denied when trying to mount image as a drive. I've already checked the permissions and have full access to the image. Any ideas?

Mind you I don't use /like Vista, but maybe:

Have you tried running as "true Admin"?
www.boot-land.net/foru...topic=4057

With UAC disabled?
www.boot-land.net/foru...&st=25

jaclaz
Back to top
View user's profile
MMachor
Member


Joined: Apr 25, 2008
Posts: 69
Location: Canton, OH

PostPosted: Sun Nov 30, 2008 8:17 pm    Post subject: Re: Mounting an image Reply with quote

Have tried both with the same results. Thanks though. I'll keep trying untill I find something.
Back to top
View user's profile Visit poster's website
MMachor
Member


Joined: Apr 25, 2008
Posts: 69
Location: Canton, OH

PostPosted: Fri Dec 05, 2008 3:18 pm    Post subject: Re: Mounting an image Reply with quote

I have been using ImDisk. Seems to work good, and is a freeware tool.
Back to top
View user's profile Visit poster's website
jaclaz
Senior Member


Joined: Nov 16, 2007
Posts: 420
Location: Near Florence - Italy

PostPosted: Sun Dec 07, 2008 12:28 pm    Post subject: Re: Mounting an image Reply with quote

MMachor wrote:
I have been using ImDisk. Seems to work good, and is a freeware tool.
I don't get it.

You had just posted that IMDISK did not work for you? Shocked

Does it work or does it not?

jaclaz
Back to top
View user's profile
keydet89
Senior Member


Joined: Oct 19, 2004
Posts: 2373
Location: NoVA

PostPosted: Sun Dec 07, 2008 4:53 pm    Post subject: Re: Mounting an image Reply with quote

hogfly wrote:

Cygwin should be able to provide this through the loopback adapter.

I'm looking at Cygwin now...any thoughts on using mount to mount a dd image?

From here:
sources.redhat.com/cyg...html#mount

I don't see where I can use '-o' to mount a dd image as a read-only file system.

For mounting a .iso file on Vista, this may work:
www.howtogeek.com/howt...ows-vista/

Thanks
Back to top
View user's profile Visit poster's website AIM Address
hogfly
Senior Member


Joined: Oct 06, 2004
Posts: 288
Location: New York

PostPosted: Sun Dec 07, 2008 6:22 pm    Post subject: Re: Mounting an image Reply with quote

A few posts down from that quote it was discussed that cygwin can't mount images. I've since moved on and just simply use a linux virtual machine. SIFT works great and autoexports the samba share RO. For more enterprise level work I have a dedicated linux box that I put images on and remotely mount. I gave up on mount image pro (issues with the cache buffer updating A times during operation), and I am not going to pay for ASR smart mount...sorry but linux mount works just fine for me.
Back to top
View user's profile Visit poster's website
MMachor
Member


Joined: Apr 25, 2008
Posts: 69
Location: Canton, OH

PostPosted: Sun Dec 07, 2008 7:21 pm    Post subject: Re: Mounting an image Reply with quote

ImDisk is now working. Don't know why it went through a spell of not working, but haven't had a problem recently. Funny thing is that I did not change anything either. Not sure what its problem was for a while.
Back to top
View user's profile Visit poster's website
Display posts from previous:   
Post new topic   Reply to topic   Printer Friendly Page     Forum Index -> General Discussion All times are GMT - 6 Hours
Go to page Previous  1, 2, 3, 4, 5, 6, 7  Next
Page 5 of 7


Jump to:  
You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot vote in polls in this forum


Use of this website signifies your agreement to the Terms of Use/Privacy Policy available here.

All logos and trademarks in this site are property of their respective owner. The comments are property of their posters, all the rest © 2010 Forensic Focus


Interactive software released under GNU GPL, Code Credits, Privacy Policy
.: fisubsilver shadow phpbb2 style by Daz :: CPG-Nuke port by norseman :: ported to CPG-Dragonfly by jamin :.